Ping Buscador Ultrassônico

O Ping))) é um buscador ultrassônico da Parallax. Detecta a distância do objeto mais próximo em frente ao sensor (até 3 metros). Funciona enviando um pulso de sinais ultrassônicos e recebendo o eco quando ele rebate. A placa Arduino envia um pulso curto para disparar a detecção, e então tenta captar um pulso no mesmo pino. A duração do segundo pulso é igual ao tempo do sinal ultrassônico em viajar até o sensor e rebater de volta ao sensor. Usando a velocidade do som, este tempo pode ser convertido em distância.

Circuito

O pino de 5V do Ping))) é conectado ao pino de 5V na placa Arduino, o pino terra é conectado ao pino terra, e o pino de sinal é conectado ao pino digital 7 do Arduino.

Código

int pingPin = 7;

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  long duration, inches, cm;

  // The PING))) is triggered by a HIGH pulse of 2 or more microseconds.
  // We give a short LOW pulse beforehand to ensure a clean HIGH pulse.
  pinMode(pingPin, OUTPUT);
  digitalWrite(pingPin, LOW);
  delayMicroseconds(2);
  digitalWrite(pingPin, HIGH);
  delayMicroseconds(5);
  digitalWrite(pingPin, LOW);

  // The same pin is used to read the signal from the PING))): a HIGH
  // pulse whose duration is the time (in microseconds) from the sending
  // of the ping to the reception of its echo off of an object.
  pinMode(pingPin, INPUT);
  duration = pulseIn(pingPin, HIGH);

  // convert the time into a distance
  inches = microsecondsToInches(duration);
  cm = microsecondsToCentimeters(duration);

  Serial.print(inches);
  Serial.print("in, ");
  Serial.print(cm);
  Serial.print("cm");
  Serial.println();

  delay(100);
}

long microsecondsToInches(long microseconds)
{
  // According to Parallax's datasheet for the PING))), there are
  // 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
  // second).  This gives the distance travelled by the ping, outbound
  // and return, so we divide by 2 to get the distance of the obstacle.
  // See: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
  return microseconds / 74 / 2;
}

long microsecondsToCentimeters(long microseconds)
{
  // The speed of sound is 340 m/s or 29 microseconds per centimeter.
  // The ping travels out and back, so to find the distance of the
  // object we take half of the distance travelled.
  return microseconds / 29 / 2;
}

O conteúdo desta página é uma tradução para o português a partir do site original do Arduino.